Première partie : séparation .fla et .as

package 
{
	import flash.display.FrameLabel;
	import flash.display.MovieClip;
	import flash.events.Event;
 
	/**
	 * ...
	 * @author Nicolas Gans
	 */
	public class Animation extends MovieClip
	{
 
		public function Animation():void
		{
			trace("Animation instanciée");
 
			// méthode 2
			addEventListener(Event.COMPLETE, ecouteurAnimationTerminee);
 
			// méthode 3
			// utilisation de la fonction non-documentée addFrameScript
			// ATTENTION : les numéros d'image commencent à 0
			// donc 89 = 90ème image
			// ATTENTION 2 : tout le code présent sur la frame est écrasé !
			addFrameScript(89, frameAnimationTerminee);
 
			// méthode 3bis
			// on peut combiner tout cela avec des étiquettes
			// currentLabels renvoie un tableau d'objets FrameLabel
			var etiquettes:Array = currentLabels;
 
			for each (var label:FrameLabel in etiquettes)
			{
				trace(label.frame, " : ", label.name);
			}
 
			// ATTENTION : le numéro de frame d'un FrameLabel commence à 1 et non à 0 !!
			addFrameScript(etiquettes[0].frame - 1, frameAnimationMilieu);
		}
 
		// METHODE 1
		// méthode appellée depuis le scénario de l'animation
		// plus performant et moins gourmand en mémoire
		private function animationTerminee():void
		{
			trace("Animation terminée");
		}
 
		// METHODE 2
		// diffusion d'un événement depuis le scénario
		private function ecouteurAnimationTerminee(e:Event):void
		{
			trace("Evénement COMPLETE diffusé depuis le scénario");
		}
 
		// METHODE 3
		// addFrameScript : une fonction se déclenche automatiquement quand la tête de lecture
		// parvient à telle image
		private function frameAnimationTerminee():void
		{
			trace("Animation terminéee avec addFrameScript");
			stop();
		}
 
		// METHODE 3bis
		// addFrameScript avec étiquette
		private function frameAnimationMilieu():void
		{
			trace("Animation milieu");
		}
 
	}
 
}

gotoAndStop(10);
// occurrence placée à l’image 10
monClip.play();
Error #1009: Il est impossible d'accéder à la propriété ou à la méthode d'une référence d'objet nul.

package 
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import flash.system.*;
 
	/**
	 * ...
	 * @author Nicolas Gans
	 */
	public class Main extends MovieClip 
	{
 
		public function Main():void
		{
 
			stop();
			etape1_btn.addEventListener(MouseEvent.CLICK, etape1);
			etape2_btn.addEventListener(MouseEvent.CLICK, etape2);
			etape3_btn.addEventListener(MouseEvent.CLICK, etape3);
 
		}
 
		private function etape1(e:MouseEvent):void
		{
			// Fonctionne avec le Flash Player 10
			// mais pas avec le Flash Player 9
			gotoAndStop("etape1");
			etape_txt.text = "Etape 1";
			perso_mc.alpha = Math.random();
 
		}
 
		private function etape2(e:MouseEvent):void
		{
			gotoAndStop("etape2");
			etape_txt.text = "Etape 2";
			tete_mc.alpha = Math.random();
		}
 
		private function etape3(e:MouseEvent):void
		{
			gotoAndStop("etape3");
			etape_txt.text = "Etape 3";
			couronne_mc.alpha = Math.random();
		}
 
	}
 
}

// écouter l’événement RENDER
addEventListener(Event.RENDER, onRender);
// déplacer la tête de lecture
gotoAndStop(10);
// invalidation du Stage
stage.invalidate();
 
// ciblage du clip dans l’écouteur
private function onRender(e:Event):void
{
monClip.play();
}

addFrameScript(9, imageDix);
gotoAndStop(10);
 
private function imageDix() :void
{
monClip.play();
}

// ne fonctionne pas
gotoAndStop(10);
monClip.alpha = Math.random();
 
// fonctionne
monConteneur.gotoAndStop(10);
monConteneur.monClip.alpha = Math.random();

package 
{
	import flash.display.DisplayObject;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.ui.Keyboard;
 
	/**
	 * ...
	 * @author Nicolas Gans
	 */
	public class Mario extends Sprite 
	{
 
		private var touches:Object = new Object();
		private var sens:Number;
		private var vitesse:Number = 8;
 
		public var isJumping:Boolean;
 
		private var _displayed:DisplayObject;
 
		public static const JUMP_FINISHED:String = "jumpFinished";
 
		public function Mario():void
		{
			sens = scaleX;
 
			// on nettoie la displayList
			while (numChildren > 0) removeChildAt(0);
 
			// clip affiché par défaut
			displayed = repos_mc;
 
			addEventListener(Event.ADDED_TO_STAGE, activation);
		}
 
		private function activation(e:Event):void
		{
			stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDown);
			stage.addEventListener(KeyboardEvent.KEY_UP, keyUp);
			addEventListener(Event.ENTER_FRAME, loop);
			// événement diffusé sur la dernière frame du clip saute_mc
			saute_mc.addEventListener(JUMP_FINISHED, onJumpFinished);
		}
 
		// gestion affichage / retrait des états
		private function set displayed(value:DisplayObject):void
		{
			// on supprime l'état en cours
			if (_displayed != null && contains(_displayed)) removeChild(_displayed);
			// on le remplace par le nouvel état
			_displayed = addChild(value);
		}
 
		// gestion des actions en fonction des touches enfoncées
		private function loop(e:Event):void 
		{
 
			if (touches[Keyboard.SPACE] && !isJumping)
			{
				saute();
			}
 
			if (touches[Keyboard.LEFT])
			{
				deplace(Keyboard.LEFT);
			}
			else if (touches[Keyboard.RIGHT])
			{
				deplace(Keyboard.RIGHT);
			}
 
			if (touches[Keyboard.DOWN] && !isJumping)
			{
				displayed = assis_mc;
			}
 
		}
 
		private function keyDown(e:KeyboardEvent):void 
		{
			touches[e.keyCode] = true;
		}
 
		private function keyUp(e:KeyboardEvent):void 
		{
			touches[e.keyCode] = false;
			if (!isJumping) displayed = repos_mc;
		}
 
		private function saute():void
		{
			isJumping = true;
			saute_mc.gotoAndPlay(2);
			displayed = saute_mc;
		}
 
		private function onJumpFinished(e:Event):void 
		{
			isJumping = false;
			displayed = repos_mc;
		}
 
		private function deplace(pSens:int):void
		{
			if (_displayed == assis_mc) return;
			if (!isJumping) displayed = marche_mc;
 
			if (pSens == Keyboard.LEFT)
			{
				scaleX = -sens;
				x -= vitesse;
			}
			else
			{
				scaleX = sens;
				x += vitesse;
			}
		}
	}
 
}
 
}