Compiler des .fla différents

package
{
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.URLRequest;
	import flash.system.ApplicationDomain;
	import flash.utils.describeType;
	import flash.utils.getDefinitionByName;
 
	/**
	 * ...
	 * @author Nicolas Gans
	 */
	public class Main extends Sprite
	{
 
		private var chargeur:Loader;
		// le nom des classes chargées
		private var assetsClassName:Array = ["Perso1", "Perso2"];
		private var localeLib:Object = new Object();
 
		public function Main():void
		{
			chargeur = new Loader();
			chargeur.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
			chargeur.load(new URLRequest("bibliotheque.swf"));
 
			createPerso1_btn.addEventListener(MouseEvent.CLICK, instanciate);
			createPerso2_btn.addEventListener(MouseEvent.CLICK, instanciate);
		}
 
		private function onComplete(e:Event):void
		{
			// récupération d'une instance d'ApplicationDomain
			// sur la propriété applicationDomain du contentLoaderInfo (e.target)
			var appDomain:ApplicationDomain = LoaderInfo(e.target).applicationDomain;
 
			// on crée dynamiquement une bibliotheque locale
			for each (var className:String in assetsClassName)
			{
				if (appDomain.hasDefinition(className))
				{
					localeLib[className] = appDomain.getDefinition(className) as Class;
				}
			}
 
			// pour infos
			for (var prop:String in localeLib)
			{
				trace(prop, ":", localeLib[prop]);
			}
		}
 
		private function instanciate(e:MouseEvent):void
		{
 
			// on crée dynamiquement la classe
			var MaClasse:Class = (e.currentTarget == createPerso1_btn) ? localeLib["Perso1"] : localeLib["Perso2"];
 
			// on pourrait en savoir plus sur la classe avec describeType
			//trace(describeType(MaClasse));
			trace(getSuperType(MaClasse));
 
			// puis on l'instancie
			// on doit typer avec le super-type de la classe
			// on pourrait ici utiliser une interface pour avoir un typage plus fort
			var perso:MovieClip = new MaClasse();
			perso.scaleX = perso.scaleY = Math.random() * .4 + .3;
			perso.x = Math.random() * (stage.stageWidth - perso.width);
			perso.y = Math.random() * (stage.stageHeight - perso.height - 40);
			addChild(perso);
 
		}
 
		// petite méthode pour connaître dynamiquement le superType d'un asset
		private function getSuperType(pClass:Class):String
		{
			var superType:String = describeType(pClass).factory.extendsClass[0].@type;
			return superType.split("::")[1];
		}
	}
 
}

[Embed (source=’image.jpg’)]
var ClasseImage:Class

package
{
	import flash.display.Bitmap;
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.media.Sound;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	// classes issues du framework Flex : indispensables pour utiliser l'embed dans Flash CS4
	import mx.core.*;
 
	/**
	 * ...
	 * @author Nicolas Gans
	 */
	public class Main extends MovieClip
	{
 
		// attention : le chemin source se fait depuis le répertoir où se trouve
		// le fichier .as, pas depuis la racine du projet !!
		[Embed (source="assets/LogoRegart.jpg")]
		var LogoRegart:Class;
 
		[Embed (source="assets/son.mp3")]
		var SonExterne:Class;
 
		[Embed (source="assets/bibliotheque.swf", symbol="Personnage")]
		var Personnage:Class;
 
		[Embed(source='assets/SerifaStd-Light.otf',
		fontName='maPolice',
		mimeType = 'application/x-font',
		unicodeRange = 'U+0030-U+0039, U+0041-U+0051, U+0052-U+007A')]
		// chiffres de 0 à 9, les minuscules de a à z et les majuscules de A à Z
		// Attention : ne pas utiliser ce nom de classe pour choisir sa typo via un TextFormat
		// ou une CSS externe, mais la propriété fontName, dans notre cas 'maPolice'
		var font:Class;
 
		private var monSon:Sound;
		private var conteneurLogo:Sprite;
		private var monLogo:Bitmap;
		private var monPerso:Sprite;
 
		public function Main():void
		{
 
			// LOGO ======================================================
			conteneurLogo = new Sprite();
			conteneurLogo.x = conteneurLogo.y = 40;
 
			monLogo = new LogoRegart();
			conteneurLogo.addChild(monLogo);
			addChild(conteneurLogo);
			conteneurLogo.buttonMode = true;
 
			// SON ======================================================
			monSon = new SonExterne();
			conteneurLogo.addEventListener(MouseEvent.CLICK, onLogoClick);
 
			// MOVIECLIP ======================================================
			monPerso = new Personnage() as Sprite;
			//trace(flash.utils.describeType(monPerso));
			monPerso.x = 220;
			monPerso.y = 140;
			monPerso.scaleX = monPerso.scaleY = .8;
			addChild(monPerso);
 
			// FONT =========================================================
			var champTexte:TextField = new TextField();
			champTexte.x = 400;
			champTexte.y = 200;
			// ne pas oublier de passer embedFonts à true !
			champTexte.width = 120;
			champTexte.wordWrap = true;
			champTexte.embedFonts = true;
			champTexte.autoSize = TextFieldAutoSize.LEFT;
			champTexte.rotation = -10;
			champTexte.text = "Lorem ipsum dolor sit amet, consectetur adipiscing elit.";
 
			// on passe en premier argument du constructeur le fontName défini dans l'embed : "maPolice"
			var tf:TextFormat = new TextFormat("maPolice", 22, 0xCC0000);
			champTexte.setTextFormat(tf);
 
			addChild(champTexte);
 
		}
 
		private function onLogoClick(e:MouseEvent):void
		{
			monSon.play();
		}
 
	}
 
}

package
{
	import flash.display.Sprite;
	import flash.text.Font;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	/**
	 * ...
	 * @author Nicolas Gans
	 */
	public class Main extends Sprite
	{
 
		[Embed(source='Calibri_font.swf',
		fontName = 'Calibri'
		)]
		private static var CalibriRegular:Class;
 
		[Embed(source='Calibri_font.swf',
		fontName = 'Calibri',
		fontStyle = 'italic'
		)]
		private static var CalibriItalic:Class;
 
		[Embed(source='Calibri_font.swf',
		fontName = 'Calibri',
		fontWeight = 'bold'
		)]
		private static var CalibriBold:Class;
 
		public function Main()
		{
 
			regular_txt.embedFonts = true;
			regular_txt.text = "Je peux parler en Calibri regular...";
			//regular_txt.rotation = 2;
			var tf:TextFormat = new TextFormat("Calibri", 22, 0xFFFFFF);
			regular_txt.setTextFormat(tf);
 
			italic_txt.embedFonts = true;
			italic_txt.text = "Mais aussi en Calibri italic...";
			tf = new TextFormat("Calibri", 22, 0xFFFFFF);
			tf.italic = true;
			//italic_txt.rotation = 2;
			italic_txt.setTextFormat(tf);
 
			bold_txt.embedFonts = true;
			bold_txt.text = "Ou encore en Calibri bold...";
			tf = new TextFormat("Calibri", 22, 0xFFFFFF);
			tf.bold = true;
			//bold_txt.rotation = 2;
			bold_txt.setTextFormat(tf);
 
			french_txt.embedFonts = true;
			french_txt.text = "Et je n'embarque que les 140 caractères français.";
			tf = new TextFormat("Calibri", 13, 0xFFFFFF);
			tf.leading = -2;
			french_txt.setTextFormat(tf);
 
		}
 
	}
 
}

package  
{
	import flash.display.Sprite;
 
	// classes du framework Flex intégrées 
	// via le rpc.swc et le framework.swc
	import mx.rpc.soap.*;
	import mx.core.*;
	import mx.rpc.events.*;
 
	import flash.events.MouseEvent;
 
	/**
	 * ...
	 * @author Nicolas Gans
	 */
	public class Main extends Sprite
	{
		private var monService:WebService;
 
		public function Main() 
		{
			monService = new WebService();
			// mx.rpc.soap.LoadEvent (hérite de WSDLLoadEvent)
			monService.addEventListener(LoadEvent.LOAD, onWSDLLoad);
			monService.loadWSDL("http://www.boyzoid.com/comp/randomQuote.cfc?wsdl");
 
			bouton.addEventListener(MouseEvent.CLICK, getQuoteClick);
		}
 
		function onWSDLLoad(e:LoadEvent):void
		{
			trace(e);
			// on écoute le résultat 
			monService.getQuote.addEventListener(ResultEvent.RESULT, getQuoteResult);
			// on écoute les éventuels échecs de l'appel 
			monService.getQuote.addEventListener(FaultEvent.FAULT, getQuoteFault);
			// appel de la méthode distante getQuote() sur le webservice
			monService.getQuote(true);
			texte.htmlText = "Retrieving quote...";
		}
 
		function getQuoteClick(e:MouseEvent):void
		{
			monService.getQuote(true);
			texte.htmlText = "Retrieving quote...";
		}
 
		function getQuoteResult(e:ResultEvent):void
		{
			trace(e.result);
			texte.htmlText = e.result as String;
		}
 
		function getQuoteFault(e:FaultEvent):void
		{
			trace(e);
			texte.htmlText = "Oups, le webservice n'a pas l'air de fonctionner...";
		}
 
	}
 
}